1. Homepage
  2. DataWeave (2.4)
  3. DataWeave リファレンス
  4. dw::Core

  5. now

now

now(): DateTime

現在の日付と時刻で ​DateTime​ (日時) 値を返します。

例

次の例では、​now()​ を使用して、現在の日付と時刻を ​DateTime​ (日時) 値として返します。また、特定のタイムゾーンの日時を返す方法も示しています。Java 8 のタイムゾーンがサポートされます。

ソース

%dw 2.0
output application/json
---
{
   nowCalled: now(),
   nowCalledSpecificTimeZone: now() >> "America/New_York"
}

出力

{
  "nowCalled": "2019-08-26T13:32:10.64-07:00",
  "nowCalledSpecificTimeZone": "2019-08-26T16:32:10.643-04:00"
}

例

次の例では、有効なセレクターによる ​now()​ 関数の使用を示します。​now() as Number​ でエポック時間を取得する方法も示します。 その他の例は、​「日時 (dw::Core 型)」を参照してください。

ソース

%dw 2.0
output application/json
---
{
  now: now(),
  epochTime : now() as Number,
  nanoseconds: now().nanoseconds,
  milliseconds: now().milliseconds,
  seconds: now().seconds,
  minutes: now().minutes,
  hour: now().hour,
  day: now().day,
  month: now().month,
  year: now().year,
  quarter: now().quarter,
  dayOfWeek: now().dayOfWeek,
  dayOfYear: now().dayOfYear,
  offsetSeconds: now().offsetSeconds,
  formattedDate: now() as String {format: "y-MM-dd"},
  formattedTime: now() as String {format: "hh:m:s"}
}

出力

{
  "now": "2019-06-18T16:55:46.678-07:00",
  "epochTime": 1560902146,
  "nanoseconds": 678000000,
  "milliseconds": 678,
  "seconds": 46,
  "minutes": 55,
  "hour": 16,
  "day": 18,
  "month": 6,
  "year": 2019,
  "quarter": 2,
  "dayOfWeek": 2,
  "dayOfYear": 169,
  "offsetSeconds": -25200,
  "formattedDate": "2019-06-18",
  "formattedTime": "04:55:46"
}