1. ホームページ
  2. DataWeave
  3. 言語ガイド
  4. サポートされるデータ形式

  5. マルチパート形式

マルチパート (フォームデータ) 形式

MIME タイプ: multipart/form-data

ID: multipart

DataWeave ではマルチパートサブタイプ (特に ​form-data​) がサポートされます。この形式では、各パートの形式に関係なく、1 つのペイロード内で複数の異なるデータパートを処理できます。パートの開始と終了を区別するには、境界を使用します。各パートのメタデータはヘッダーを介して追加できます。

DataWeave では、特定の ​Object​ 構造を使用して、マルチパートドキュメントを表します。

type Multipart = {
  preamble?: String,
  parts: {
    _?: MultipartPart
  }
}
type MultipartPart = {
  headers?: {
    "Content-Disposition"?: {
      name: String,
      filename?: String
    },
    "Content-Type"?: String
  },
  content: Any
}
weave

例

次の例は、マルチパート形式の使用方法を示しています。

例: マルチパート

次の例は、DataWeave で単純なマルチパートコンテンツを読み取る方法を示しています。

入力

マルチパート入力は、DataWeave ソースへのペイロードとして機能します。

--34b21
Content-Disposition: form-data; name="text"
Content-Type: text/plain
Book
--34b21
Content-Disposition: form-data; name="file1"; filename="a.json"
Content-Type: application/json
{
"title": "Java 8 in Action",
"author": "Mario Fusco",
"year": 2014
}
--34b21
Content-Disposition: form-data; name="file2"; filename="a.html"
Content-Type: text/html

<title> Available for download! </title>
--34b21--
text

ソース

この DataWeave スクリプトは、マルチパート入力ペイロードを DataWeave (dw) 形式に変換します。

%dw 2.0
output application/dw
---
payload
weave

出力

この出力は、DataWeave (dw) 形式でマルチパート入力がどのように表されるのかを示しています。​raw​ および ​content​ 値は、簡潔にするために短縮されています。完全な値はこれよりも長くなります。

例: パートのデータにアクセスして変換する

DataWeave スクリプト内で、​parts​ 要素を選択し、任意のパートのデータにアクセスし、変換できます。操作は配列に基づくことができます。また、パートを参照するための名前がパートに設定されている場合は、キーに基づくことができます。パートのデータには ​content​ キーワードを介してアクセスでき、ヘッダーには ​headers​ キーワードを介してアクセスできます。

入力

次の例は、個別の DataWeave スクリプトへの入力として機能します。3 つのパートで構成される ​34b21​ 境界を含む未加工の ​multipart/form-data​ ペイロードを以下に示します。

  • text​ という名前の ​text/plain

  • file1​ という名前の ​application/json​ ファイル (​a.json​)

  • file2​ という名前の ​text/html​ ファイル (​a.html​)

未加工のマルチパートデータ:
--34b21
Content-Disposition: form-data; name="text"
Content-Type: text/plain

Book
--34b21
Content-Disposition: form-data; name="file1"; filename="a.json"
Content-Type: application/json

{
  "title": "Java 8 in Action",
  "author": "Mario Fusco",
  "year": 2014
}
--34b21
Content-Disposition: form-data; name="file2"; filename="a.html"
Content-Type: text/html

<!DOCTYPE html>
<title>
  Available for download!
</title>
--34b21--
text

ソース

次の DataWeave スクリプトは、入力として未加工の ​multipart/form-data​ ペイロードを使用し、​Book:a.json​ を生成します。

マルチパートコンテンツの読み取り:
%dw 2.0
output text/plain
---
payload.parts.text.content ++ ':' ++ payload.parts[1].headers.'Content-Disposition'.filename
dataweave

例: マルチパートコンテンツを生成する

DataWeave がパートのリスト (各パートにヘッダーとコンテンツが含まれる) を含むオブジェクトを構築するマルチパートコンテンツを生成できます。次の DataWeave スクリプトでは、ペイロード内で HTML データを使用できる場合に、(以前に分析した) 未加工のマルチパートデータを生成します。

DataWeave ドキュメントの出力の一貫性を確保するために、この例では ​boundary​ プロパティをハードコード化します。 ただし、多くの場合、DataWeave によってランダムな境界が生成されて出力 MIME タイプに追加されるため、このプロパティをハードコード化する必要はありません。
マルチパートコンテンツの書き込み:

パートの名前が ​Content-Disposition​ ヘッダーに明示的に提供されていない場合は、キーによりパートの名前が決まります。また、DataWeave は、サポートされる形式からのコンテンツを処理できるだけでなく、HTML など、サポートされない形式への参照からコンテンツを処理できます。

次の例は、現在のペイロードをマルチパートフォームデータのファイルパートとして送信する方法を示しています。次のような DataWeave スクリプトを使用する必要があります。

%dw 2.0
input payload application/xml
output multipart/form-data boundary="----myboundary----"
---
{
  parts: {
    filePart: {
      headers: {
        "Content-Disposition": {
          "name": "<NAME>",
          "filename": "<FILE_NAME>.<FILE_EXTENSION>"
        },
        "Content-Type": "<FILE_CONTENT-TYPE>"
      },
      content: payload
    },
    otherJsonPart: {
      content: '{"name": "sampleFile.xml", "sampleFile": {"type": "sample"} }'
    }
  }
}
dataweave

  • boundary​ は境界値を設定します (例: "----myboundary----"​)。

  • <NAME>​ はファイルのタグ名です (例: "sampleFile"​)。

  • <FILE_NAME>.<FILE_EXTENSION>​ はペイロードのコンテンツを入力するためのファイル名です (例: "sampleFile.xml"​)。

  • <FILE_CONTENT-TYPE>​ は送信するファイルのコンテンツと一致させます (例: "application/xml"​)。

  • ファイルのコンテンツは現在のペイロードです。

この例には、マルチパートに 2 つのパート (ファイルと ​otherJsonPart​) が含まれています。さらにパートを追加する場合は、​parts:{}​ セクションの下に次の形式で追加します。

  <PART_NAME>: {
    content: <PART_CONTENT>
  }
dataweave

  • <PART_NAME>​ は引用符なしのパート名です (例: json​)。

  • <PART_CONTENT>​ はそのパートのコンテンツです (例: '{"name": "sampleFile.xml", "sampleFile": {"type": "sample"} }'​)。

次の XML 入力を前提とします。

DataWeave スクリプトは次のようになります。

%dw 2.0
output multipart/form-data  boundary="----myboundary----"
---
{
  parts: {
    filePart: {
      headers: {
        "Content-Disposition": {
          "name": "test",
          "filename": "sampleFile.xml"
        },
        "Content-Type": "application/xml"
      },
      content: payload
    },
    otherJsonPart: {
      content: '{"name": "sampleFile.xml", "sampleFile": {"type": "sample"} }'
    }
  }
}
dataweave

出力マルチパートは次のようになります。

例: マルチパートペイロードを反復処理する

次の例は、DataWeave がペイロードのすべてのパートを反復処理して各パートを個別に処理する方法を示しています。

ソース

%dw 2.0
output application/json
var multi = '--34b21
Content-Disposition: form-data; name="text"
Content-Type: text/plain

Book
--34b21
Content-Disposition: form-data; name="file1"; filename="a.json"
Content-Type: application/json

{
"title":"Java 8 in Action",
"author":"Mario Fusco",
"year":2014
}
--34b21
Content-Disposition: form-data; name="file2"; filename="a.html"
Content-Type: text/html

<!DOCTYPE html>
<title>
Available for download!
</title>
--34b21--'
var parsed = read(multi, "multipart/form-data", {boundary:'34b21'})
---
parsed.parts mapObject ((value, key, index) -> {(index): key})
dataweave

出力

{
  "0": "text",
  "1": "file1",
  "2": "file2"
}
json

例: ^mediaType および ^mimeType メタデータセレクターの使用

^mimeType​ セレクターは、パラメーターなしの値の MIME タイプ (​application/json​ など) を返します。​^mediaType​ セレクターは、対照的に MIME タイプとそれに関連する他のパラメーター (​application/json;charset=UTF-16​ など) を返します。

次の例では、マルチパート入力を異なる形式のマルチパート出力に変換する方法を示しています。この DataWeave スクリプトでは、​^mimeType​ セレクターと ​^mediaType​ セレクターの両方を使用して新しいマルチパートコンテンツを生成します。

入力

マルチパート入力には複数のコンテンツタイプがあります。この場合は、非標準の区切り文字が含まれる ​application/json​ と ​application/csv​ です。

----------------------------049709565842371278701691
Content-Type: application/json
Content-Disposition: form-data; name="order"

{
"name": "order1",
"id": 123,
"content": "orderContent"
}
----------------------------049709565842371278701691
Content-Type: application/csv;separator=.
Content-Disposition: form-data; name="partner"

partnerName.id
mulesoft.1
----------------------------049709565842371278701691--
text

ソース

この DataWeave スクリプトでは、​output multipart/form-data​ MIME タイプを定義してマルチパート入力をマルチパート出力に変換します。マルチパート出力データには 2 つのパートが含まれます。

  • orderAck

注文の受信の肯定応答を伴うテキストが含まれます。コンテンツタイプは ​text/plain​ です。 ^mimeType` セレクターは、メッセージのパートとしてコンテンツタイプを記録する場合に役に立ちます。

  • partner

元のパートナー自体が含まれます。今回はコンテンツタイプが ​payload.parts..^mediaType​ である点に注意してください。^mediaType セレクターには、​application/csv​ コンテンツを解析する区切り文字も含まれます。

%dw 2.0
input payload multipart boundary='boundary1'
output multipart boundary='test2'
---
{
  parts : {
    orderAck : {
      headers : {
        "Content-Type": "text/plain"
      },
      content : "Order payload of type " ++ payload.parts.order.content.^mimeType ++ " and id " ++ (payload.parts.order.content.id as String) ++ " received. Receipt available."
    },
    partner: {
      headers : {
        "Content-Type": payload.parts.partner.content.^mediaType
      },
      content : payload.parts.partner.content
    }
  }
}
dataweave

出力

--test2
Content-Type: text/plain
Content-Disposition: form-data; name="orderAck"

Order payload of type application/json and id 123 received. Receipt available.
--test2
Content-Type: application/csv;separator=.
Content-Disposition: form-data; name="partner"

partnerName.id
mulesoft.1
--test2--
text

Configuration のプロパティ

DataWeave では、この形式の以下の設定プロパティがサポートされています。

Reader のプロパティ

この形式は、入力データを読み取るための指示を提供するプロパティを受け入れます。

パラメーター 型 デフォルト 説明

boundary

String

null

マルチパートの ​boundary​ 値。パートを区切る文字列です。

defaultContentType

String

'application/octet-stream'

multipart/*​ 形式のパートで使用するデフォルトのコンテンツタイプを設定します。設定すると、このプロパティは​『システムプロパティ』​ ​com.mulesoft.dw.multipart.defaultContentType​ の設定よりも優先されます。

2021 年 8 月リリースの Mule 4.3.0-20210719 の DataWeave 2.3 (2.3.0-20210720) で導入されました。​

Writer のプロパティ

この形式は、出力データを書き込むための指示を提供するプロパティを受け入れます。

パラメーター 型 デフォルト 説明

boundary

String

null

マルチパートの ​boundary​ 値。パートを区切る文字列です。

bufferSize

Number

8192

バッファライターのサイズ (バイト)。値は 8 よりも大きい必要があります。

deferred

Boolean

false

true​ に設定すると、出力をデータストリームとして生成し、スクリプトの実行は生成されたコンテンツがコンシュームされるまで延期されます。

有効な値は、​true​ または ​false​ です。

サポートされる MIME タイプ

この形式では、次の MIME タイプがサポートされます。

MIME タイプ

multipart/*