1. ホームページ
  2. DataWeave
  3. DataWeave リファレンス
  4. dw::util::Coercions

  5. toNumber

toNumber

toNumber(dateTime: DateTime, unit: MillisOrSecs | Null = null): Number

選択した単位に応じて ​DateTime​ 値を秒数またはミリ秒数に変換する ​toNumber​ のバリエーション。

DataWeave バージョン 2.4.0 で導入されました。

パラメーター

名前 説明

dateTime

Number​ 値に変換する ​DateTime​ 値。

unit

使用する時間の単位 (​"milliseconds"​ または ​"seconds"​)。​null​ 値の場合、​"seconds"​ が使用されます。

例

次の例では、さまざまな入力での ​toNumber​ の動作を示します。

ソース

%dw 2.0
import * from dw::util::Coercions
output application/json
---
{
    epoch: toNumber(|2015-10-01T23:57:59Z|),
    millis: toNumber(|2015-10-01T23:57:59Z|, "milliseconds")
}
DataWeave

出力

{
  "epoch": 1443743879,
  "millis": 1443743879000
}
DataWeave

toNumber(period: Period, unit: PeriodUnits | Null = null): Number

Period​ 値を時間数、分数、秒数、ミリ秒数、またはナノ秒数 (​nanos​) に変換する ​toNumber​ のバリエーション。

DataWeave バージョン 2.4.0 で導入されました。

パラメーター

名前 説明

period

Number​ 値に変換する ​Period​ 値。

unit

指定された ​period​ に適用する単位: hours​、​minutes​、​seconds​、​milliseconds​、または ​nanos​。

例

次の例では、さまざまな入力での ​toNumber​ の動作を示します。

ソース

%dw 2.0
import * from dw::util::Coercions
output application/json
---
{
    toSecondsEx1: toNumber(|PT1H10M|, "seconds"),
    toSecondsEx2: toNumber(|PT1M7S|, "milliseconds")
}
DataWeave

出力

{
  "toSecondsEx1": 4200,
  "toSecondsEx2": 67000
}
Json

toNumber(value: String | Key, format: String | Null = null, locale: String | Null = null): Number

String​ 値または ​Key​ 値を ​Number​ 値に変換して、形式とロケールを受け入れる ​toNumber​ のバリエーション。

DataWeave バージョン 2.4.0 で導入されました。

パラメーター

名前 説明

value

Number​ 値に変換する ​String​ 値または ​Key​ 値。

format

value​ に適用する省略可能な書式設定。 ​format​ は ​10 進数​値および ​10​ 未満の 1 つの整数のプレースホルダーとして ​#​ または ​0​ (ただし両方ではない) を受け入れます。1 つの小数点しか使用できません。​null​ 値または空の ​String​ 値は ​Number​ 値に対して無効です。他の文字を使用するとエラーが発生します。

locale

使用する省略可能な ISO 3166 国コード (​US​、​AR​、​ES​ など)。​null​ または欠落値では JVM のデフォルトが使用されます。

例

次の例では、さまざまな入力での ​toNumber​ の動作を示します。

ソース

%dw 2.0
import * from dw::util::Coercions
var myKey = keysOf({"123" : "myValue"})
output application/json
---
 {
     "default": toNumber("1.0"),
     "withFormat": toNumber("0.005",".00"),
     "withLocal": toNumber("1,25","#.##","ES"),
     "withExtraPlaceholders": toNumber("5.55","####.####"),
     "keyToNumber": toNumber(myKey[0])
 }
DataWeave

出力

{
  "default": 1.0,
  "withFormat": 0.005,
  "withLocal": 1.25,
  "withExtraPlaceholders": 5.55,
  "keyToNumber": 123
}
Json