keysOf

keysOf<K, V>(obj: { (K)?: V }): Array<K>

入力オブジェクト内のキー - 値ペアからのキーの配列を返します。

返されるキーは Key (キー) 型に属します。各キーを文字列として返すには、代わりに namesOf を使用します。

DataWeave バージョン 2.3.0 で導入されました。

パラメーター

名前説明

名前	説明
`object`	評価するオブジェクト。

object

評価するオブジェクト。

例

次の例では、入力オブジェクト内のキー - 値ペアからのキーを返します。

ソース

%dw 2.0
output application/json
---
{ "keysOf" : keysOf({ "a" : true, "b" : 1}) }DataWeave

出力

{ "keysOf" : ["a","b"] }JSON

例

次の例は、keysOf と namesOf の違いを示しています。 keysOf は XML 入力からの属性 (name と lastName) と名前空間 (xmlns) を保持していますが、namesOf はそれらを保持しないため、null を返しています。

ソース

%dw 2.0
var myVar = read('<users xmlns="http://test.com">
                     <user name="Mariano" lastName="Achaval"/>
                     <user name="Stacey" lastName="Duke"/>
                  </users>', 'application/xml')
output application/json
---
{ keysOfExample: flatten([keysOf(myVar.users) map $.#,
                          keysOf(myVar.users) map $.@])
}
++
{ namesOfExample: flatten([namesOf(myVar.users) map $.#,
                    namesOf(myVar.users) map $.@])
}DataWeave

出力

{
  "keysOfExample": [
    "http://test.com",
    "http://test.com",
    {
      "name": "Mariano",
      "lastName": "Achaval"
    },
    {
      "name": "Stacey",
      "lastName": "Duke"
    }
  ],
  "namesOfExample": [
    null,
    null,
    null,
    null
  ]
}JSON

keysOf(obj: Null): Null

keysOf を null 値に使用できるようにするヘルパー関数。

DataWeave バージョン 2.4.0 で導入されました。