nodeExists

nodeExists(value: Any, callback: (value: Any, path: Path) -> Boolean): Boolean

特定のツリー内のいずれかのノードが、指定された条件に対して検証された場合、true を返します。

DataWeave バージョン 2.2.2 で導入されました。

パラメーター

名前説明

名前	説明
`value`	検索する値。
`callback`	入力 `value` に適用する条件。

value

検索する値。

callback

入力 value に適用する条件。

例

次の例では、名前と姓で各ユーザーをチェックします。value を $ で、path を $$ で参照することもできます。

ソース

%dw 2.0
import * from dw::util::Tree
var myObject =  {
     user: [{
         name: "mariano",
         lastName: "achaval",
         friends: [
             {
                 name: "julian"
             },
             {
                 name: "tom"
             }
         ]
     },
     {
         name: "leandro",
         lastName: "shokida",
         friends: [
             {
                 name: "peter"
             },
             {
                 name: "robert"
             }
         ]

     }
     ]
 }
output application/json
---
{
    mariano : myObject nodeExists ((value, path) -> path[-1].selector == "name" and value == "mariano"),
    julian : myObject nodeExists ((value, path) -> path[-1].selector == "name" and value == "julian"),
    tom : myObject nodeExists ($$[-1].selector == "name" and $ == "tom"),
    leandro : myObject nodeExists ($$[-1].selector == "name" and $ ==  "leandro"),
    peter : myObject nodeExists ($$[-1].selector == "name" and $ == "peter"),
    wrongField: myObject nodeExists ($$[-1].selector == "wrongField"),
    teo: myObject nodeExists ($$[-1].selector == "name" and $ == "teo")
}DataWeave
コンテンツを展開する

出力

{
  "mariano": true,
  "julian": true,
  "tom": true,
  "leandro": true,
  "peter": true,
  "wrongField": false,
  "teo": false
}Json