指定した XML 属性の削除

XML タグ内から機密データが含まれていることがわかっている特定の属性を削除できます。この DataWeave の例では、渡される要素とその子から特定の XML 属性を削除する関数を DataWeave ヘッダーで定義します。

この例では、以下を使用します。

  • 各要素を調べる mapObject

  • XML 要素の属性を参照する @

  • 存在している XML 属性のみをリストし、子要素がオブジェクトである場合にのみ関数を再帰的にコールする if および else

  • 子が Object 型かどうかをチェックする is

  • XML 属性のリストから要素を削除する -

  • 値がない場合に出力 XML に自己終了タグが表示されるようにする出力ディレクティブの inlineCloseOn="empty"

DataWeave
%dw 2.0
input payload application/json
output application/xml inlineCloseOn="empty"
var removeAttribute = (element,attrName) ->
  element mapObject (value, key) -> {
    (key) @(
        (
          if (key.@?)
            (key.@ - attrName)
          else {}
        )
    ) :
    if (value is Object)
      removeAttribute(value, attrName)
    else value
  }
---
removeAttribute(payload, "password")
入力
<users>
  <user username="Julian" password="1234"/>
  <user username="Mariano" password="4321"/>
</users>
出力
<?xml version='1.0' encoding='US-ASCII'?>
<users>
  <user username="Julian"/>
  <user username="Mariano"/>
</users>

Was this article helpful?

💙 Thanks for your feedback!

Edit on GitHub